Stili di programmazione Cobol

Altre pagine:	1] Sintassi Cobol		3] Struttura e organizzazione dei file
	2] Poche righe non bastano		4] Accesso ai file Cobol

Poche righe non bastano

Navigando in rete si possono trovare siti che, per dare una idea della struttura di un programma scritto in Cobol, utilizzano un esempio che potrei definire classico.
Si tratta di Helloworld realizzato con poche righe di codice.

Il programma, semplicissimo, non fa nient’altro che stampare sul video questa scritta ed é stato ripreso nella didattica di molti altri linguaggi come primo esempio di introduzione al linguaggio in esame, diventando un vero classico: molto spesso, un programmatore che vuole imparare un nuovo linguaggio, inizia i suoi esercizi provando a scrivere un programma che stampi a video "Hello World!" in quel linguaggio.

000001 IDENTIFICATION DIVISION.
000002 PROGRAM-ID.     HELLO-WORLD.
000003*
000004 ENVIRONMENT DIVISION.
000005*
000006 DATA DIVISION.
000007*
000008 PROCEDURE DIVISION.
000009*
000010 MAIN.
000011     DISPLAY "Hello World!".
000012     STOP RUN.
000013*

Da questo esempio si potrebbe dedurre che bastano poche righe di codice per realizzare un programma Cobol, ma in pratica non è proprio così.

Programmare in Cobol vuol dire scrivere righe e righe di codice.

Dalla mia esperienza posso dire che:

     Bullet Il codice sorgente di un "programmino" è composto da 800 - 1500 righe.

     Bullet Il codice sorgente di un "programma normale" contiene fino a 3000 righe.

     Bullet Il codice sorgente di un "programma grande" può raggiungere comodamente le 10 - 15 mila righe.

Lo stile

Se analizziamo il codice sorgente di un programma Cobol scritto da chi ha appreso Cobol prima del 1985 - 1986 ossia con la versione Cobol-75, e uno scritto da chi ha iniziato direttamente dalla versione Cobol-85 possiamo notare una sostanziale differenza di stile.

Nel primo vengono utilizzati i comandi GO TO e PERFORM THRU, mentre nel secondo questi comandi sono totalmente assenti.
Il motivo può essere ricercato nel fatto che il comando PERFORM in Cobol-75 offriva delle possibilità limitate in cui non erano previste le varianti WITH TEST AFTER/BEFORE.

Personalmente utilizzo, senza problemi di sorta, il primo stile di programmazione utilizzando, laddove necessita, la controversa istruzione GO TO.

Go non ammesso Per taluni il comando GO TO non va assolutamente utilizzato, anzi andrebbe bandito dal linguaggio Cobol.
Al suo posto dovrebbe essere utilizzato il comando PERFORM solo nella forma senza la variante THRU.

Penso che sia meglio utilizzare un semplice GO TO piuttosto che cercare di ottenere lo stesso risultato con PERFORM nei formati WITH TEST AFTER/BEFORE combinato con UNTIL e magari anche dei FLAG di controllo di flusso.

Inoltre non bisogna dimenticare che Cobol appartiene alla classe dei linguaggi di programmazione imperativi.

Un programma ben strutturato e perciò ben leggibile si può ottenere, a mio avviso, anche utilizzando in modo corretto e non sconsiderato il comando GO rispettando però delle regole ben precise per evitare di ottenere dei programmi stile spaghetti.

Dal punto di vista della funzionalità i due stili non portano a differenze degne di nota, anche se GO TO rispetto a PERFORM dovrebbe risultare più performante poichè non impegna lo stack pointer.

Ritengo importante che nell’ ambito di una applicazione, rispettivamente azienda, tutti i programmi siano realizzati nello stesso stile e specialmente ben documentati.

Per fare un esempio ho utilizzato un programma realizzato da un mio collega nei primi giorni del corso Cobol svolto nel mese di ottobre 2006 presso EasiRun Europa e ho cercato di riscriverlo secondo il mio stile.
I commenti sono volutamente stati ridotti al minimo.

La codifica secondo il mio stile:

000001 IDENTIFICATION DIVISION.
000002 PROGRAM-ID. STILE-1.
000003 AUTHOR. Hermes Schaub.
000004*-----------------------------------------------------------------
000005 ENVIRONMENT DIVISION.
000006*
000007 CONFIGURATION SECTION.
000008*
000009 SOURCE-COMPUTER. HP-PORTABLE-PC.
000010 OBJECT-COMPUTER. HP-PORTABLE-PC.
000011*
000012 INPUT-OUTPUT SECTION.
000013*
000014 FILE-CONTROL.
000015     SELECT E-DATEI ASSIGN TO DISC
000016                    "E:\WorkF\UEB1E1.DAT"
000017                    ORGANIZATION IS LINE SEQUENTIAL. 
000018*
000019     SELECT A-DATEI ASSIGN TO DISC
000020                    "E:\WorkF\UEB1A1-2.DAT"
000021                    ORGANIZATION IS LINE SEQUENTIAL.  
000022*-----------------------------------------------------------------
000023 DATA DIVISION.
000024*
000025 FILE SECTION.
000026 FD  E-DATEI
000027           LABEL RECORD STANDARD.
000028*
000029 01  E-SATZ-1 PIC X(80). 
000030 FD  A-DATEI
000031           LABEL RECORD STANDARD.
000032*                 
000033 01  A-SATZ-1 PIC X(80).
000034 01  A-SATZ-2 PIC X(85).
000035*-----------------------------------------------------------------
000036/      
000037 WORKING-STORAGE SECTION.
000038*
000039 01  WS-ARTIKELSATZ-1.
000040     05  WS-SA-1          PIC X(1).
000041     05  WS-ARTNR-1.
000042         10  WS-ARTGRP-1  PIC 9(3).
000043         10  WS-LFDNR-1   PIC 9(3).
000044     05  WS-ARTBEZ-1      PIC X(20).
000045     05  WS-KOSTEN-1      PIC 9(3)V9(2).
000046     05  WS-VWKOST-1      PIC 9(2)V9(1).
000047     05  WS-VTPROV-1      PIC 9(2)V9(1).
000048     05  WS-PREIS-1       PIC 9(4)V9(2).
000049     05  WS-MENGE-1       PIC 9(3).
000050 01  WS-ENDCALC-1.
000051     05  WS-ENDUMSATZ-1    PIC 9(12)V9(2) VALUE ZERO.  
000052     05  WS-ENDGEWINN-1    PIC 9(12)V9(2) VALUE ZERO.    
000053     05  WS-ENDRENT-1      PIC 9(12)V9(2) VALUE ZERO.
000054*
000055 01  A-ARTIKELSATZ-1.
000056     05  A-SA-1           PIC X(1).
000057     05  A-ARTNR-1.        
000058         10  A-ARTGRP-1   PIC 9(3).
000059         10  A-LFDNR-1    PIC 9(3).
000060     05  A-ARTBEZ-1       PIC X(20).
000061     05  A-UMSATZ-1       PIC 9(7)V9(2).
000062     05  A-GEWINN-1       PIC 9(7)V9(2).
000063     05  A-RENTAB-1       PIC 9(2)V9(2).       
000064 
000065 01  A-ENDCALC-1.
000066     05  A-UMDES-1        PIC X(13) VALUE "TOTALUMSATZ: ".
000067     05  A-ENDUMSATZ-1    PIC Z(6)9(6)V9(2).  
000068     05  A-GEWDES-1       PIC X(15) VALUE "  TOTALGEWINN: ".
000069     05  A-ENDGEWINN-1    PIC Z(6)9(6)V9(2).    
000070     05  A-RENDES-1       PIC X(15) VALUE "  TOTALRENTAB: ".
000071     05  A-ENDRENT-1      PIC Z(6)9(6)V9(2).
000072*-----------------------------------------------------------------
000073/      
000074 PROCEDURE DIVISION.
000075*
000076 MAIN SECTION.
000077*
000078*              ELABORAZIONE PRINCIPALE
000079 00.
000080     PERFORM OPEN-START  THRU OPEN-START-E.
000081*
000082 01.
000083     PERFORM ELAB1       THRU ELAB99.
000084*
000085 02.
000086     PERFORM CLOSE-START THRU CLOSE-END.
000087*
000088 99.
000089    GOBACK.
000090* 
000091*-----------------------------------------------------------------
000092*        LEGGI FILE E PREPARA CAMPI DI OUTPUT
000093*
000094 ELAB1.
000095*
000096     READ E-DATEI INTO WS-ARTIKELSATZ-1
000097          AT END PERFORM TOT1 THRU TOT9
000098                 GO ELAB99.
000099*
000100*    PREPARA CAMPI DI OUTPUT
000101*
000102 ELAB2.
000103     MOVE WS-SA-1     TO A-SA-1.
000104     MOVE WS-ARTGRP-1 TO A-ARTGRP-1.
000105     MOVE WS-LFDNR-1  TO A-LFDNR-1.
000106     MOVE WS-ARTBEZ-1 TO WS-ARTBEZ-1.
000107     PERFORM CALCULATE-START THRU CALCULATE-END.
000108*
000109     WRITE A-SATZ-1 FROM A-ARTIKELSATZ-1.  
000110*
000111     GO ELAB1.                      *> LOOP LETTURA FILE 
000112*
000113 ELAB99.
000114     EXIT.
000115*
000116*-----------------------------------------------------------------
000117*                   
000118*                     CALCOLARE TOTALI
000119*            
000120 CALCULATE-START. 
000121*                    
000122     COMPUTE A-UMSATZ-1 = WS-MENGE-1 * WS-PREIS-1.
000123     COMPUTE A-GEWINN-1 = A-UMSATZ-1 - 
000124                          ((WS-VTPROV-1 * WS-PREIS-1 * 
000125                          WS-MENGE-1 / 100) + 
000126                          (WS-VWKOST-1 * 
000127                          WS-KOSTEN-1 * 
000128                          WS-MENGE-1 / 100) + 
000129                          (WS-KOSTEN-1 * WS-MENGE-1)).
000130     COMPUTE A-RENTAB-1     = A-GEWINN-1 * 100 / A-UMSATZ-1.
000131     COMPUTE WS-ENDUMSATZ-1 = WS-ENDUMSATZ-1 + A-UMSATZ-1.
000132     COMPUTE WS-ENDGEWINN-1 = WS-ENDGEWINN-1 + A-GEWINN-1.
000133     COMPUTE WS-ENDRENT-1   = WS-ENDRENT-1 + A-RENTAB-1.
000134*
000135 CALCULATE-END.
000136     EXIT.
000137*
000138*-----------------------------------------------------------------
000139*            
000140*               PREPARA E SCRIVI RECORD FINALE
000141 TOT1. 
000142     MOVE WS-ENDUMSATZ-1 TO A-ENDUMSATZ-1.
000143     MOVE WS-ENDGEWINN-1 TO A-ENDGEWINN-1.
000144     MOVE WS-ENDRENT-1   TO A-ENDRENT-1.
000145*
000146     WRITE A-SATZ-2 FROM A-ENDCALC-1.  
000147*
000148 TOT9.
000149     EXIT.                                          
000150*
000151*-----------------------------------------------------------------
000152*
000153*                 APRI FILE
000154 OPEN-START.    
000155     OPEN INPUT  E-DATEI
000156          OUTPUT A-DATEI.
000157*
000158 OPEN-START-E.
000159     EXIT.
000160*
000161*-----------------------------------------------------------------
000162*
000163*                 CHIUDI FILE
000164 CLOSE-START.
000165     CLOSE E-DATEI
000166           A-DATEI.
000167 CLOSE-END.
000168     EXIT.   
000169*
000170*
000171*                 *** END STILE-1.CBL  ***

La codifica nello stile del mio collega:

000001 IDENTIFICATION DIVISION.
000002 PROGRAM-ID. STILE-2.
000003 AUTHOR. Collega.
000004*-----------------------------------------------------------------
000005 ENVIRONMENT DIVISION.
000006*
000007 CONFIGURATION SECTION.
000008 SOURCE-COMPUTER. HP-PORTABLE-PC.
000009 OBJECT-COMPUTER. HP-PORTABLE-PC.
000010*
000011 INPUT-OUTPUT SECTION.
000012 FILE-CONTROL.
000013     SELECT E-DATEI ASSIGN TO "C:\WorkF\UEB1E1.DAT"
000014                    ORGANIZATION IS LINE SEQUENTIAL. 
000015     SELECT A-DATEI ASSIGN TO "C:\WorkF\UEB1A1.DAT"
000016                    ORGANIZATION IS LINE SEQUENTIAL.  
000017*-----------------------------------------------------------------
000018 DATA DIVISION.
000019 FILE SECTION.
000020*
000021*
000022*
000023 FD  E-DATEI.
000024 01  E-SATZ-1 pic x(80). 
000025*
000026*
000027*
000028 FD  A-DATEI.
000029 01  A-SATZ-1 pic x(80).
000030 01  A-SATZ-2 pic x(85).
000031/
000032 WORKING-STORAGE SECTION.
000033*
000034*
000035*
000036 01  WS-ARTIKELSATZ-1.
000037     05  WS-SA-1          PIC X(1).
000038     05  WS-ARTNR-1.
000039         10  WS-ARTGRP-1  PIC 9(3).
000040         10  WS-LFDNR-1   PIC 9(3).
000041     05  WS-ARTBEZ-1      PIC A(20).
000042     05  WS-KOSTEN-1      PIC 9(3)V9(2).
000043     05  WS-VWKOST-1      PIC 9(2)V9(1).
000044     05  WS-VTPROV-1      PIC 9(2)V9(1).
000045     05  WS-PREIS-1       PIC 9(4)V9(2).
000046     05  WS-MENGE-1       PIC 9(3).
000047*
000048 01  WS-ENDCALC-1.
000049     05  WS-ENDUMSATZ-1    PIC 9(12)V9(2) VALUE ZERO.  
000050     05  WS-ENDGEWINN-1    PIC 9(12)V9(2) VALUE ZERO.    
000051     05  WS-ENDRENT-1      PIC 9(12)V9(2) VALUE ZERO.
000052*
000053 01  A-ARTIKELSATZ-1.
000054     05  A-SA-1           PIC X(1).
000055     05  A-ARTNR-1.        
000056         10  A-ARTGRP-1   PIC 9(3).
000057         10  A-LFDNR-1    PIC 9(3).
000058     05  A-ARTBEZ-1       PIC A(20).
000059     05  A-UMSATZ-1       PIC 9(7)V9(2).
000060     05  A-GEWINN-1       PIC 9(7)V9(2).
000061     05  A-RENTAB-1       PIC 9(2)V9(2).       
000062 
000063 01  A-ENDCALC-1.
000064     05  A-UMDES-1        PIC A(13) VALUE "TOTALUMSATZ: ".
000065     05  A-ENDUMSATZ-1    PIC Z(6)9(6)V9(2).  
000066     05  A-GEWDES-1       PIC A(15) VALUE "  TOTALGEWINN: ".
000067     05  A-ENDGEWINN-1    PIC Z(6)9(6)V9(2).    
000068     05  A-RENDES-1       PIC A(15) VALUE "  TOTALRENTAB: ".
000069     05  A-ENDRENT-1      PIC Z(6)9(6)V9(2).
000070*
000071 01  EOF-CONTROL          PIC A(1) VALUE "N".      
000072*-----------------------------------------------------------------
000073/
000074 PROCEDURE DIVISION.
000075 
000076 MAIN SECTION.
000077 MAIN-START.   
000078     PERFORM OPEN-START 
000079*
000080*            
000081     PERFORM READ-START
000082     PERFORM WITH TEST BEFORE UNTIL EOF-CONTROL = "J"    
000083         PERFORM SETOUTPUT-START
000084         PERFORM WRITE-START                           
000085         PERFORM READ-START 
000086     END-PERFORM
000087     PERFORM SETENDOUTPUT-START
000088     PERFORM WRITEEND-START
000089     PERFORM CLOSE-START
000090         STOP RUN
000091     .
000092 MAIN-END.
000093*-----------------------------------------------------------------
000094 MANAGEFILE SECTION.
000095 OPEN-START.    
000096     OPEN INPUT E-DATEI
000097          OUTPUT A-DATEI
000098     .
000099 OPEN-END.
000100*-----------------------------------------------------------------
000101 READ-START.
000102     READ E-DATEI INTO WS-ARTIKELSATZ-1
000103          AT END MOVE 'J' TO EOF-CONTROL
000104     .
000105 READ-END.       
000106      EXIT.
000107
000108*-----------------------------------------------------------------
000109 WRITEFILE SECTION.
000110 SETOUTPUT-START.                 
000111     MOVE WS-SA-1 TO A-SA-1
000112     MOVE WS-ARTGRP-1 TO A-ARTGRP-1
000113     MOVE WS-LFDNR-1 TO A-LFDNR-1
000114     MOVE WS-ARTBEZ-1 TO WS-ARTBEZ-1
000115     PERFORM CALCULATE-START
000116     .
000117 SETOUTPUT-END.
000118*-----------------------------------------------------------------
000119 SETENDOUTPUT-START.                 
000120     MOVE WS-ENDUMSATZ-1 TO A-ENDUMSATZ-1
000121     MOVE WS-ENDGEWINN-1 TO A-ENDGEWINN-1
000122     MOVE WS-ENDRENT-1 TO A-ENDRENT-1
000123     .
000124 SETENDOUTPUT-END.
000125*-----------------------------------------------------------------
000126 WRITE-START.
000127     WRITE A-SATZ-1 FROM A-ARTIKELSATZ-1
000128     .
000129 WRITE-END.
000130 WRITEEND-START.
000131     WRITE A-SATZ-2 FROM A-ENDCALC-1
000132     .
000133 WRITEEND-END.
000134*-----------------------------------------------------------------
000135 CLOSE-START.
000136     CLOSE E-DATEI
000137           A-DATEI
000138     .
000139 CLOSE-END.
000140     EXIT.
000141*-----------------------------------------------------------------
000142 CALCULATE SECTION.
000143 CALCULATE-START.              
000144     COMPUTE A-UMSATZ-1 = WS-MENGE-1 * WS-PREIS-1
000145     COMPUTE A-GEWINN-1 = A-UMSATZ-1 - 
000146                          ((WS-VTPROV-1 * WS-PREIS-1 * 
000147                          WS-MENGE-1 / 100) + 
000148                          (WS-VWKOST-1 * 
000149                          WS-KOSTEN-1 * 
000150                          WS-MENGE-1 / 100) + 
000151                          (WS-KOSTEN-1 * WS-MENGE-1))
000152     COMPUTE A-RENTAB-1 = A-GEWINN-1 * 100 / A-UMSATZ-1
000153     COMPUTE WS-ENDUMSATZ-1 = WS-ENDUMSATZ-1 + A-UMSATZ-1
000154     COMPUTE WS-ENDGEWINN-1 = WS-ENDGEWINN-1 + A-GEWINN-1
000155     COMPUTE WS-ENDRENT-1 = WS-ENDRENT-1 + A-RENTAB-1
000156     .
000157 CALVULATE-END.
000158     EXIT.    
000169*
000170*
000168*                 *** END STILE-2.CBL  ***

Come prelevare questi codici

Pagina precedente

Pagina successiva

Cobol in pratica

Poche righe non bastano

Lo stile