Replica dati Cobol in MySQL con ODBC

Altre pagine:	1] MySQL	4] Gestione completa dei dati
	2] Preparazione	5] Le eccezioni
	3] Replica dati in MySQL	6] Accedere i dati

Replicare i dati di RM/COBOL in MySQL

Lo scopo di questo semplice programma è quello di popolare una tabella di un database MySQL utilizzando i dati memorizzati in un file RM/COBOL.

La struttura dei file RM/COBOL

Questo potrebbe essere un file ad organizzazione index dove come chiave primaria viene usato il numero indirizzo.

000041*
000042 FD   F01
000043                     LABEL RECORD        STANDARD.
000044*
000045*
000046*
000047 1    F01REC.
000048  2   F01KEY.
000049   3  F0101       PIC 9(4).         *> Numero indirizzo
000050  2   F0102       PIC X(25).        *> Cognome e nome
000051  2   F0103       PIC X(25).        *> Via
000052  2   F0104       PIC X(15).        *> Citta'
000053  2   F0105       PIC X(11).        *> Nazione
000054*

La struttura della tabella MySQL

In pratica ricopia la struttura del file RM/COBOL dove come chiave univoca viene usato il numero indirizzo.

Tabella MySQL

Variante 1 - Tramite ODBC

Con questa variante i dati di RM/COBOL vengono scritti direttamente nella tabella del database.
Per semplificarne al massimo la lettura non ho volutamente incluso la gestione degli status al modulo ODBC.

MY-EX-02.CBL

000001 IDENTIFICATION DIVISION.
000002*
000003*
000004*
000005*                    POPOLARE UN DATABASE MYSQL
000006*                    --------------------------
000007*     Programma di esempio per l'accesso a MySQL di RMCobol
000008*     lo status di SQL viene controllato il modo minimale
000009*     per semplificare l'esempio.
000010*      
000011 PROGRAM-ID.  MY-EX-02.
000012*
000013*
000014*
000015 ENVIRONMENT DIVISION.
000016 CONFIGURATION SECTION.
000017 SOURCE-COMPUTER.  RMC10.
000018 OBJECT-COMPUTER.  RMC10.
000019*
000020*
000021 INPUT-OUTPUT SECTION.
000022 FILE-CONTROL.
000023*
000024*
000025*
000026*                 SCHEDARIO INDIRIZZI
000027*
000028*
000029     SELECT F01         ASSIGN TO DISC
000030           "INDZZI.DAT"
000031                        ORGANIZATION    INDEXED
000032                        ACCESS          DYNAMIC
000033                        RECORD KEY      F01KEY
000034                        FILE STATUS     ERF01.
000035*
000036*
000037*
000038 DATA DIVISION.
000039 FILE SECTION.
000040*
000041*
000042 FD   F01
000043                     LABEL RECORD        STANDARD.
000044*
000045*
000046*
000047 1    F01REC.
000048  2   F01KEY.
000049   3  F0101       PIC 9(4).         *> Numero indirizzo
000050  2   F0102       PIC X(25).        *> Cognome e nome
000051  2   F0103       PIC X(25).        *> Via
000052  2   F0104       PIC X(15).        *> Citta'
000053  2   F0105       PIC X(11).        *> Nazione
000054*
000055*
000056*
000057*
000058*
000059/      
000060 WORKING-STORAGE SECTION.
000061*
000062 1   PROGRAMMA.
000063  2  FILLER           PIC X(08)        VALUE "MY-EX-02".
000064  2  FILLER           PIC X            VALUE "-".
000065  2  COMPILATO        PIC 9(6).
000066 78  DATE-COMP                         VALUE IS DATE-COMPILED.
000067*
000068*
000069*      Campi riservati per la gestione degli status files.
000070*
000071 1    TXE.
000072  2   FILLER     PIC X(14)       VALUE "Error on file ".
000073  2   FILEN      PIC X(11). 
000074*
000075 1    TXE1.
000076  2   FILLER     PIC X(14)       VALUE "Status is  ".
000077  2   FILESTEX.
000078  3   FILEST     PIC XX.    
000079  3   FILLER     PIC XX.    
000080*
000081*
000082*      Costanti & campi di lavori
000083*
000084 1    TXS        PIC X(80)       VALUE SPACES.
000085 1    WC         PIC XX          VALUE "00".
000086 1    SLF        PIC  9.    
000087 1    A1         PIC  X.
000088*
000089*      Campi specifici ogni ogni file
000090*
000091 1    ERF01      PIC XX.
000092*
000093 1   TXEA      PIC X(31)   VALUE "Terminare il programma = $".
000094*
000095*
000096 1  C1                   PIC 9(8).
000097 1  DIS8                 PIC ZZZZZZZ9-.
000098 1  DIS6                 PIC ZZZZZ9-.
000099*
000100*                      COMANDI SQL
000101*
000102* A) Inserire 
000103*
000104 01 WS-INSERT-SQL.
000105    05 FILLER                       VALUE
000106     "INSERT INTO Indirizzi (Numero, Nome, Via, Citta, Nazione
000107-   " ) VALUES (".
000108    05 WS-NUMERO         PIC 9(04).  
000109    05 FILLER                      VALUE ", '".
000110    05 WS-NOME           PIC X(25).  
000111    05 FILLER                      VALUE "', '".
000112    05 WS-VIA            PIC X(25).  
000113    05 FILLER                      VALUE "', '".
000114    05 WS-CITTA          PIC X(15).
000115    05 FILLER                      VALUE "', '".
000116    05 WS-NAZIONE        PIC X(11).
000117    05 FILLER                       VALUE "') ;".
000118*
000119* B) Cancellare
000120*
000121 01 WS-delete-SQL.
000122    05 FILLER                       VALUE
000123      "DELETE  FROM Indirizzi ;".
000124*
000125/
000126 COPY "lisqlall.cpy".
000127*
000128*
000129/                    
000130 PROCEDURE DIVISION.
000131*
000132*
000133*
000134 DECLARATIVES.
000135*
000136 DEC01 SECTION.
000137     USE AFTER ERROR PROCEDURE F01.
000138 DEC0101.
000139     MOVE ERF01            TO FILEST.
000140     MOVE "INDZZI.DAT"     TO FILEN.
000141*
000142 END DECLARATIVES.
000143*
000144*
000145/
000146 HAUPT SECTION.
000147*
000148*
000149*
000150 A-1.
000151     MOVE DATE-COMP TO COMPILATO
000152     DISPLAY PROGRAMMA LINE 1 POSITION 60 ERASE.
000153     DISPLAY "POPOLARE DATABASE MYSQL" LINE 1  POSITION 30
000154             "-----------------------" LINE 2  POSITION 30
000155             "STATUS"                  LINE 13 POSITION 30.
000156*
000157     MOVE 0 TO C1.                   
000158*
000159     MOVE WC TO FILEST.
000160     OPEN INPUT F01.
000161     PERFORM TR THRU TRE.
000162*
000163     MOVE LOW-VALUE TO  F01KEY.
000164*           
000165     MOVE WC TO FILEST.
000166     START F01 KEY NOT < F01KEY.
000167     PERFORM TR THRU TRE.
000168*
000169 A-2.
000170*            CONNESSIONE ODBC
000171*
000172*
000173     SQL CONNECT DATASOURCE sql-ConnectionHandle
000174         "RMC-MY-ODBC"  *> NOME ODBC
000175         "RM-MY"        *> USER  
000176         "rmc".         *> PASSWORD
000177     IF NOT sql-OK
000178       DISPLAY
000179       "* Error connecting to data source. *" LINE 22 POSITION 1
000180       ACCEPT A1 LINE 22 POSITION 79
000181       GOBACK.
000182*
000183*
000184*
000185*        CANCELLA TUTTI I DATI DELLA TABELLA
000186*
000187*  
000188*
000189*
000190*             PREPARA IL COMANDO SQL
000191*
000192     SQL PREPARE QUERY sql-QueryHandle
000193          sql-ConnectionHandle
000194          WS-delete-SQL.
000195*             
000196*            ESEGUI IL COMANDO
000197*
000198     SQL START QUERY sql-QueryHandle.
000199*
000200     DISPLAY "Record cancellati:" LINE 10 POSITION 30.
000201*           
000202*
000203*            LEGGO LO STATUS ** ( 0 / 1 = OK  -1 = NON OK)
000204*               **) Valori per update/insert/delete
000205*
000206     SQL DESCRIBE QUERY sql-QueryHandle
000207         sql-Query-Description.
000208*
000209     IF sql-QryRowCount NOT < 0 DISPLAY "OK " LINE 13 POSITION 50
000210        ELSE                    DISPLAY "NOK" LINE 13 POSITION 50.
000211     MOVE sql-QryRowCount TO DIS8.
000212     DISPLAY DIS8 LINE 10 POSITION 50.
000213*
000214*
000215*           TERMINO LA QUERY
000216*
000217    SQL END QUERY
000218         sql-QueryHandle.
000219*
000220*
000221     DISPLAY "Record creati:" LINE 11 POSITION 30.
000222*         
000223*           
000224*
000225*          LOOP PER POPOLARE TABELLA
000226*
000227 A-3.
000228     MOVE WC TO FILEST.
000229     READ F01 NEXT.
000230     IF FILEST = "10" GO A-99.
000231     PERFORM TR THRU TRE.
000232*
000233     MOVE F0101  TO WS-NUMERO.         
000234     MOVE F0102  TO WS-NOME.
000235     MOVE F0103  TO WS-VIA.
000236     MOVE F0104  TO WS-CITTA.
000237     MOVE F0105  TO WS-NAZIONE.
000238*
000239    SQL PREPARE QUERY sql-QueryHandle
000240          sql-ConnectionHandle
000241          WS-INSERT-SQL.
000242*            
000243*
000244     SQL START QUERY sql-QueryHandle.
000245*
000246*
000247     
000248*           
000249     SQL DESCRIBE QUERY sql-QueryHandle
000250         sql-Query-Description.
000251     IF sql-QryRowCount > 0  DISPLAY "OK " LINE 13 POSITION 50
000252        ELSE                 DISPLAY "NOK" LINE 13 POSITION 50.
000253        
000254     IF sql-QryRowCount > 0
000255           ADD sql-QryRowCount TO C1.
000256     MOVE C1 TO DIS8.
000257     DISPLAY DIS8 LINE 11 POSITION 50.
000258*
000259*
000260     SQL END QUERY
000261         sql-QueryHandle.
000262*
000263     GO A-3.
000264*
000265*
000266 A-99.
000267*
000268     ACCEPT A1 LINE 22 POSITION 79.       
000269*
000270     MOVE WC TO FILEST.
000271     CLOSE F01.
000272     PERFORM TR THRU TRE.
000273*
000274*
000275*                
000276*
000277*                 DISCONNETTI ODBC
000278*
000279     SQL DISCONNECT DATASOURCE sql-ConnectionHandle.
000280*                     Terminate InstantSQL.
000281*
000282*                 SCARICO DLL 
000283*
000284     SQL SHUTDOWN.
000285*
000286     DISPLAY "* LAVORO TERMINATO *" LINE 22 POSITION 1.
000287     ACCEPT A1 LINE 22 POSITION 78.                
000288*
000289     GOBACK.
000290*
000291/
000292*        Routine controllo status file I-O
000293 TR.
000294      MOVE 0 TO SLF.
000295      IF FILEST = WC GO TRE.
000296      CALL "c$rerr"  USING FILESTEX.
000297*
000298      DISPLAY TXS LINE 18 POSITION 2 SIZE 25
000299              TXS LINE 19 POSITION 2 SIZE 25
000300              TXE LINE 18 POSITION 2 TXE1 LINE 19 POSITION 2.
000301*
000302      ACCEPT A1 LINE 19 POSITION 30 PROMPT.
000303*
000304      DISPLAY TXS LINE 18 POSITION 2 SIZE 25
000305              TXS LINE 19 POSITION 2 SIZE 25.
000306*
000307      IF A1      = "$" GOBACK.
000308      IF FILEST = "99" MOVE 1 TO SLF GO TRE. 
000309      IF A1 NOT = "#"                GO TR.
000310 TRE.
000311      EXIT.
000312*
000313*              *** END MY-EX-02.CBL ***

Variante 2 - Tramite file di scambio dati formato CSV

Tramite un programma RM/COBOL viene creato un file sequenziale con i campi separati dal carattere ; (punto e virgola).
Il file così ottenuto viene importato nel database tramite il programma incluso in MySQL MYSQLIMPORT.

Personalmente preferisco questa variante poichè richiede meno tempo per la sua realizzazione.

immagine Nella preparazione del file da importare bisogna tener conto dei seguenti punti:

     Il formato deve essere testo.
     Nome del file deve essere uguale al nome della tabella di destinazione (l’estensione è influente).
     I campi vanno separati dal carattere ";".
     immagine I campi numerici vanno editati utilizzando il formato -----9.99.
     Il carattere ' (apice) deve essere sostituito con un altro carattere.

immagine Nel catalogo dove risiede il programma MYSQLIMPORT dovrà essere presente il file di configurazione my.ini
    con i seguenti parametri:

     Configurazione my.ini
Da notare l’opzione delete che cancella dapprima i dati della tabella.

Il comando, incluso in un file batch, per importare il file:

    c:\mysql\bin\mysqlimport demo c:\dati\indirizzi.txt

immagine Il programma per la creazione del file da importare in MySQL.

MY-EX-02.CBL

000001 IDENTIFICATION DIVISION.
000002*
000003*
000004*
000005*               CREARE UN FILE PER IMPORARE IN MYSQL
000006*               ------------------------------------
000007*                      Programma esempio 
000008*
000009 PROGRAM-ID.        MY-EX-03.
000010*
000011 ENVIRONMENT DIVISION.
000012 CONFIGURATION SECTION.
000013*
000014 SOURCE-COMPUTER.           RMC10.
000015 OBJECT-COMPUTER.           RMC10.
000016*
000017*
000018 INPUT-OUTPUT SECTION.
000019 FILE-CONTROL.
000020*
000021*
000022*                 SCHEDARIO INDIRIZZI
000023*
000024*
000025     SELECT F01         ASSIGN TO DISC
000026           "INDZZI.DAT"
000027                        ORGANIZATION    INDEXED
000028                        ACCESS          SEQUENTIAL
000029                        RECORD KEY      F01KEY
000030                        FILE STATUS     ERF01.
000031*
000032*
000033*                   FILE CSV 
000034*
000035     SELECT F90         ASSIGN TO DISC
000036           "Indirizzi.txt"
000037                        ORGANIZATION LINE SEQUENTIAL
000038                        STATUS       ERF90.
000039*
000040*
000041*
000042*
000043*
000044/
000045 DATA DIVISION.
000046 FILE SECTION.
000047*
000048*
000049*
000050 FD   F01
000051                     LABEL RECORD        STANDARD.
000052*
000053*
000054*
000055 1    F01REC.
000056  2   F01KEY.
000057   3  F0101       PIC 9(4).         *> Numero indirizzo
000058  2   F0102       PIC X(25).        *> Cognome e nome
000059  2   F0103       PIC X(25).        *> Via
000060  2   F0104       PIC X(15).        *> Citta'
000061  2   F0105       PIC X(11).        *> Nazione
000062*
000063*
000064/
000065*
000066*
000067*                  FILE INPUT DA EXCEL FORMATO CVS
000068*
000069 FD   F90
000070                   RECORD VARYING FROM 1 TO 128
000071                   DEPENDING ON RSZ
000072                   LABEL RECORD STANDARD.
000073*
000074*
000075 1    F90REC.
000076  2   F90RECB   PIC X OCCURS 128.
000077 1    F90RECM   PIC X(1).
000078/
000079*
000080*
000081 WORKING-STORAGE SECTION.
000082*
000083*
000084*
000085*
000086*
000087 1   PROGRAMMA.
000088  2  FILLER           PIC X(08)        VALUE "MY-EX-03".
000089  2  FILLER           PIC X            VALUE "-".
000090  2  COMPILATO        PIC 9(6).
000091*
000092 78  DATE-COMP                         VALUE IS DATE-COMPILED.
000093*
000094*
000095*      Campi riservati per la gestione degli status files.
000096*
000097 1    TXE.
000098  2   FILLER     PIC X(14)       VALUE "Error on file ".
000099  2   FILEN      PIC X(11). 
000100*
000101 1    TXE1.
000102  2   FILLER     PIC X(14)       VALUE "Status is  ".
000103  2   FILESTEX.
000104  3   FILEST     PIC XX.    
000105  3   FILLER     PIC XX.    
000106*
000107 1    TXS        PIC X(80)       VALUE SPACES.
000108*
000109*      Costanti & campi di lavori
000110*
000111 1    WC         PIC XX          VALUE "00".
000112 1    SLF        PIC  9.    
000113 1    RSZ        PIC 9(3).
000114 1    A1         PIC  X.
000115 1    P1         PIC 9(3).
000116*
000117*      Campi specifici ogni ogni file
000118*
000119 1    ERF01      PIC XX.
000120 1    ERF90      PIC XX.  
000121*
000122*
000123/
000124 PROCEDURE DIVISION.
000125*
000126 DECLARATIVES.
000127*
000128*
000129 DEC01 SECTION.
000130     USE AFTER ERROR PROCEDURE F01.
000131 DEC0101.
000132      MOVE ERF01 TO FILEST.  MOVE "INDZZI.DAT"       TO FILEN.
000133*
000134 DEC90 SECTION.
000135     USE AFTER ERROR PROCEDURE F90.
000136 DEC9090.
000137      MOVE ERF90 TO FILEST.  MOVE "Indirizzi.csv"     TO FILEN.
000138*
000139*
000140 END DECLARATIVES.
000141/
000142*
000143/
000144 HAUPT SECTION.
000145*
000146*
000147*             
000148 A-1.
000149     PERFORM IN1 THRU IN9.
000150*
000151*
000152 A-2.
000153*       
000154     MOVE WC TO FILEST.
000155     READ F01.
000156     IF FILEST = "10" GO A-9.
000157     PERFORM TR THRU TRE.
000158*
000159*
000160     INITIALIZE F90REC.
000161*
000162*
000163*
000164     STRING F0101 DELIMITED SIZE
000165            ";"   DELIMITED SIZE
000166            F0102 DELIMITED "   "
000167            ";"   DELIMITED SIZE
000168            F0103 DELIMITED "   "
000169            ";"   DELIMITED SIZE
000170            F0104 DELIMITED "   "
000171            ";"   DELIMITED SIZE
000172            F0105 DELIMITED "   "
000173                                    INTO F90REC.
000174*
000175     PERFORM RSZE1 THRU RSZE9.           
000176*
000177     MOVE WC TO FILEST.
000178     WRITE F90REC.
000179     PERFORM TR THRU TRE.
000180*
000181     GO A-2. 
000182*
000183*
000184 A-9.
000185*
000186     DISPLAY "FINE"  LINE 22 POSITION 10 REVERSE.
000187     ACCEPT       A1 LINE 22 POSITION 79 PROMPT.
000188     PERFORM CL1 THRU CL9.
000189*
000190     GOBACK.
000191/
000192*            CALCOLO RECORD SIZE DI F90REC
000193 RSZE1.
000194     MOVE 129 TO P1.
000195*
000196 RSZE2.            
000197     SUBTRACT 1 FROM P1.
000198     IF P1 < 5 GO RSZE3.
000199     IF F90RECB(P1) = SPACES GO RSZE2.
000200*
000201 RSZE3.
000202     MOVE P1 TO RSZ.
000203*
000204 RSZE9.
000205     EXIT.                      
000206     
000207/
000208*            TEST FILE STATUS
000209*
000210 TR.
000211      MOVE 0 TO SLF.
000212      IF FILEST = WC GO TRE.
000213      CALL "c$rerr"  USING
000214                         FILESTEX.
000215      DISPLAY TXS LINE 18 POSITION 2 SIZE 25
000216              TXS LINE 19 POSITION 2 SIZE 25
000217              TXE LINE 18 POSITION 2 TXE1 LINE 19 POSITION 2.
000218      ACCEPT A1 LINE 19 POSITION 30 PROMPT.
000219      DISPLAY TXS LINE 18 POSITION 2 SIZE 25
000220              TXS LINE 19 POSITION 2 SIZE 25.
000221      IF A1 = "$" GOBACK.
000222      IF FILEST = "99" MOVE 1 TO SLF GO TRE.
000223 TRE.
000224      EXIT.
000225/
000226*                 INIZIALIZZARE
000227*
000228*
000229 IN1.
000230     MOVE DATE-COMP TO COMPILATO.
000231     DISPLAY PROGRAMMA   LINE 1 ERASE.
000232*
000233     MOVE WC TO FILEST. OPEN INPUT  F01.     PERFORM TR THRU TRE.
000234     MOVE WC TO FILEST. OPEN OUTPUT F90.     PERFORM TR THRU TRE.
000235*
000236*
000237 IN9.
000238     EXIT.
000239/
000240*                  FINE PROGRAMMA
000241 CL1.
000242       DISPLAY "END OF - " LINE 1 ERASE
000243               PROGRAMMA LINE 1  POSITION 10.
000244*
000245*
000246*
000247      MOVE WC TO FILEST. CLOSE F01.         PERFORM TR THRU TRE.
000248      MOVE WC TO FILEST. CLOSE F90.         PERFORM TR THRU TRE.
000249* 
000250*
000251 CL9.
000252     EXIT.
000253*                **** END MY-EX-03.CBL ****

immagine Questo è il file ottenuto:

Indirizzi.txt

1010;Alfreds Futterkiste;Obere Str. 57;Berlino;Germania
1020;Antonio Moreno Taquer¡a  ;Mataderos  2312;C. del Messico ;Messico
1025;Around the Horn;120 Hanover Sq.;Londra;G. Bretagna
1030;Berglunds snabbk p;Berguvsv gen  8;Lule;Svezia
1035;Blauer See Delikatessen  ;Forsterstr. 57;Mannheim;Germania
1040;Blondel pre et fils;24, place Kleber;Strasburgo;Francia
1045;B¢lido Comidas preparadas;C/ Araquil, 67;Madrid;Spagna
1055;Bottom-Dollar Markets;23 Tsawassen Blvd.;Tsawassen;Canada
1065;Cactus Comidas llevar;Cerrito 333;Buenos Aires;Argentina
1070;Centro Moctezuma;Sierras de Granada 9993  ;C. del Messico.;Messico
1075;Chop-suey Chinese;Hauptstr. 29;Berna;Svizzera
1080;Com.rcio Mineiro;Av. dos Lus¡adas, 23;San Paolo;Brasile
1085;Die Wandernde Kuh;Adenauerallee 900;Stoccarda;Germania
1090;Drachenblut Delikatessen ;Walserweg 21;Aquisgrana;Italia
1095;Du monde entier;Rue des Cinquante Otages ;Nantes;Francia
1100;Eastern Connection;35 King George;Londra;G. Bretagna
1105;Ernst Handel;Kirchgasse 6;Graz;Austria
1110;Familia Arquibaldo;Rua Or¢s, 92;San Paolo;Brasile
1120;Folies gourmandes;184, chausse de Tournai ;Lille;Francia
1125;Folk och f HB;Ékergatan 24;Brocke;Svezia
1130;France restauration;54, rue Royale;Nantes;Francia
1135;Franchi S.p.A.;Via Monte Bianco 34;Torino;Italia
1140;Frankenversand;Berliner Platz 43;Monaco di B.;Germania
1150;Galer¡a del gastr¢nomo;Rambla de Catalu¤a, 23;Barcellona;Spagna
1155;Godos Cocina T¡pica;C/ Romero, 33;Siviglia;Spagna
1160;Gourmet Lanchonetes;Av. Brasil, 442;Campinas;Brasile
1165;Great Lakes Food Market  ;2732 Baker Blvd.;Eugene;USA
1170;GROSELLA-Restaurante;5¦ Ave. Los Palos Grandes;Caracas;Venezuela
1175;Hanari Carnes;Rua do Palo, 67;Rio de Janeiro ;Brasile
1185;Hungry Grocers;8 Johnstown Road;Cork;Irlanda
1190;Kiniglich Essen;Maubelstr. 90;Brandeburgo;Germania
1210;Lazy K Kountry Store;12 Orchestra Terrace;Walla Walla;USA
1215;Lehmanns Marktstand;Magazinweg 7;Francoforte;Germania
1225;LINO-Delicateses;Ave. 5 de Mayo Porlamar  ;I. de Margarita;Venezuela
1230;Lonesome Pine Restaurant ;89 Chiaroscuro Rd.;Portland;USA
1235;Magazzini Riuniti;Via Ludovico il Moro 22  ;Bergamo;Italia
1240;Maison Dewey;Rue Joseph Bens 532;Bruxells;Belgio
1245;Mere Paillarde;43 rue St. Laurent;Montreal;Canada
1250;Morgenstern Gesundkost;Heerstr. 22;Lipsia;Germania
1255;Old World Delicatessen;2743 Bering St.;Anchorage;USA
1260;Ottilies Keseladen;Mehrheimerstr. 369;Colonia;Germania
1265;Paris specialitas;265, boulevard Charonne  ;Parigi;Francia
1270;Pericles Comidas cl sicas;Calle Dr. Jorge Cash 321 ;C. del Messico ;Messico
1275;Piccolo und mehr;Geislweg 14;Salisburgo;Austria
1280;Que Del¡cia;Rua da Panificadora, 12  ;Rio de Janeiro ;Brasile
1285;Queen Cozinha;Alameda dos Canorios, 891;San Paolo;Brasile
1290;QUICK-Stop;Taucherstraáe 10;Cunewalde;Germania
1295;Rancho grande;Av. del Libertador 900;Buenos Aires;Argentina
1300;Reggiani Caseifici;Strada Provinciale 124;Reggio Emilia  ;Italia
1305;Ricardo Adocicados;Av. Copacabana, 267;Rio de Janeiro ;Brasile
1310;Richter Supermarkt;Grenzacherweg 237;Ginevra;Svizzera
1315;Romero y tomillo;Gran V¡a, 1;Madrid;Spagna
1320;Santo Gourmet;Erling Skakkes gate 78;Stavern;Norvegia
1325;Save-a-lot Markets;187 Suffolk Ln.;Boise;USA
1330;Seven Seas Imports;90 Wadhurst Rd.;Londra;G. Bretagna
1335;Simons bistro;Vinbultet 34;Copenaghen;Danimarca
1340;Specialites du monde;25, rue Lauriston;Parigi;Francia
1345;Split Rail Beer & Ale;P.O. Box 555;Lander;USA
1350;Supremes delices;Boulevard Tirou, 255;Charleroi;Belgio
1355;The Cracker Box;55 Grizzly Peak Rd.;Butte;USA
1360;Toms Spezialitaten;Luisenstr. 48;Münster;Germania
1365;Tortuga Restaurante;Avda. Azteca 123;C. del Messico ;Messico
1370;Tradios Hipermercados;Av. Inos de Castro, 414  ;San Paolo;Brasile
1380;Vaffeljernet;Smagsäget 45;Urhus;Danimarca
1385;Victuailles en stock;2, rue du Commerce;Lione;Francia
1395;Wartian Herkku;Torikatu 38;Oulu;Finlandia
1400;Wellington Importadora;Rua do Mercado, 12;Resende;Brasile
1405;Wilman Kala;Keskuskatu 45;Helsinki;Finlandia
1410;Wolski Zajazd;ul. Filtrowa 68;Varsavia;Polonia

Come prelevare questi codici

Pagina precedente

Pagina successiva

Cobol in pratica

Replicare i dati di RM/COBOL in MySQL

La struttura dei file RM/COBOL

La struttura della tabella MySQL

Variante 1 - Tramite ODBC

Variante 2 - Tramite file di scambio dati formato CSV